;===================================================================
; JPBooks omod Script for JPBooks 11.1.20 : Irrlicht
;===================================================================
;-------------------------------------------------------------------
; ・日本語の使用は結構怪しいので注意。Script Editor上できちんと表示できれば大丈夫
; ・コードの再利用はどうぞご自由に
;-------------------------------------------------------------------

;-------------------------------------------------------------------
; お約束
;-------------------------------------------------------------------
DontInstallAnyPlugins
DontInstallAnyDataFiles

;-------------------------------------------------------------------
; ObMM Ver. Cheack
;-------------------------------------------------------------------

; 必須確認
;   CopyPlugin           0.8.0以降。
;   OblivionNewerThan    0.8.9以降
;   SetVar               0.9.1以降
;   AllowRunOnLines      1.0.0以降
;   LoadEarly            1.1.11以降
If VersionLessThan 1.1.11
	If DialogYesNo "お使いのバージョンのOblivion Mod Managerではこのomodファイルに対応してないので不具合が発生する可能性があります(1.1.11以降必須)。%NewLine%続行する場合はYes(はい)、キャンセルする場合はNo(いいえ)を選んで下さい", "Warning"
		;do nothing
	Else
		Message "インストールがキャンセルされました" "Notice"
		FatalError
	EndIf
EndIf

;-------------------------------------------------------------------
; Oblivion Ver. Cheack
;-------------------------------------------------------------------
; Oblivion
If OblivionNewerThan 1.2.0.416
	; do nothing
Else
	If DialogYesNo "Oblivionのゲームプログラムが最新版(1.2.0.416)でないので不具合が発生する可能性があります。%NewLine%続行する場合はYes(はい)、キャンセルする場合はNo(いいえ)を選んで下さい", "Warning"
		;do nothing
	Else
		Message "インストールがキャンセルされました" "Notice"
		FatalError
	EndIf
EndIf

;-------------------------------------------------------------------
; 準備
;-------------------------------------------------------------------
; 変数
SetVar FlagJPBooks 0
SetVar FlagMWJPBKS 0
SetVar FlagMerge 0
; 長すぎる命令を複数行に分割できるようにする。Select等で使用(行末\がそれ)
AllowRunOnLines

;-------------------------------------------------------------------
; JPBooks Flag
;-------------------------------------------------------------------
;選択
SelectWithDescriptions "[Main] JPBooks あなたのOblivion環境はどちらですか？", \
       "Vanilla+Shivering Isles", \
       "Vanilla(本編)とShivering Isles(公式拡張)に含まれる書籍を翻訳データに置換するModが導入されます。書籍名は英語のままです。", \
       "Vanilla", \
       "Vanilla(本編)に含まれる書籍を翻訳データに置換するModが導入されます。Shivering Isles(公式拡張)に含まれる書籍の翻訳データは含まれません。書籍名は英語のままです。"
	Case Vanilla
		SetVar FlagJPBooks 1
		Break
	Case Vanilla+Shivering Isles
		SetVar FlagJPBooks 2
		Break
	Default
		Message "入力値が不正です" "Fatal Error"
		FatalError
EndSelect

;警告 (SI無し環境でV+Sを選択した場合、警告を出す)
IfNot DataFileExists "DLCShiveringIsles.esp"
	If Equal %FlagJPBooks% 2
		If DialogYesNo "Vanilla+Shivering Islesが選択されましたが、Shivering Islesが入っていないようなので問題が発生する可能性があります。%NewLine%続行する場合はYes(はい)、キャンセルする場合はNo(いいえ)を選んで下さい", \
		               "Warning"
			;do nothing
		Else
			Message "インストールがキャンセルされました" "Notice"
			FatalError
		EndIf
	EndIf
EndIf

;警告 (SI有り環境でVを選択した場合、告知を出す)
If DataFileExists "DLCShiveringIsles.esp"
	If Equal %FlagJPBooks% 1
		If DialogYesNo "Vanillaが選択されましたが、あなたの環境はShivering Islesも入っているようです。%NewLine%続行する場合はYes(はい)、キャンセルする場合はNo(いいえ)を選んで下さい", \
		               "Notice"
			;do nothing
		Else
			Message "インストールがキャンセルされました" "Notice"
			FatalError
		EndIf
	EndIf
EndIf


;-------------------------------------------------------------------
; morrowindJPbooks Flag #1
;-------------------------------------------------------------------
If DialogYesNo "The Elder Scrolls 3 : Morrowindに登場した書籍を追加するMod(morrowindJPbooks)を導入しますか？", \
               "[Optional] morrowindJPbooks #1"
	SetVar FlagMWJPBKS 1
Else
	;do nothing
EndIf

;-------------------------------------------------------------------
; morrowindJPbooks Flag #2
;-------------------------------------------------------------------
;選択
If Equal %FlagMWJPBKS% 1
	SelectWithDescriptions "[Optional] morrowindJPbooks #2 ： バリエーション選択", \
  	     "morrowindJPbooks", \
 	      "Morrowind書籍の追加と各種おまけ機能を追加しています。特に理由がない場合はこちらで良いでしょう。", \
 	      "morrowindJPbooks_light", \
 	      "通常版からおまけ機能を取り除いたLight版です。"
		Case morrowindJPbooks
			SetVar FlagMWJPBKSSelect 1
			Break
		Case morrowindJPbooks_light
			SetVar FlagMWJPBKSSelect 2
			Break
		Default
			Message "入力値が不正です" "Fatal Error"
			FatalError
	EndSelect
EndIf

;-------------------------------------------------------------------
;Merge Flag
;-------------------------------------------------------------------
IfNot Equal %FlagJPBooks% 0
	IfNot Equal %FlagMWJPBKS% 0
		If DialogYesNo "マージされたModを導入しますか？" "Merge"
			SetVar FlagMerge 1
		Else
			;do nothing
		EndIf
	EndIf
EndIf

;-------------------------------------------------------------------
;Copy ：copyは実際にはScriptの最後にまとめて行われる。よってこの順番でも問題は無い
;-------------------------------------------------------------------
;Merged
If Equal %FlagMerge% 1
	; JPBooks_Vanilla
	If Equal %FlagJPBooks% 1
		; + morrowindJPbooks
		If Equal %FlagMWJPBKSSelect% 1
			CopyPlugin "100_merged\\JPBooks_Merged(V+M).esp" "JPBooks_Merged(V+M).esp"
			LoadEarly "JPBooks_Merged(V+M).esp"
			SetVar InstallFiles "JPBooks_Merged(V+M).esp%NewLine%"
		EndIf
		; + morrowindJPbooks_light
		If Equal %FlagMWJPBKSSelect% 2
			CopyPlugin "100_merged\\JPBooks_Merged(V+ML).esp" "JPBooks_Merged(V+ML).esp"
			LoadEarly "JPBooks_Merged(V+ML).esp"
			SetVar InstallFiles "JPBooks_Merged(V+ML).esp%NewLine%"
		EndIf
	EndIf

	; JPBooks_Vanilla+SI
	If Equal %FlagJPBooks% 2
		; + morrowindJPbooks
		If Equal %FlagMWJPBKSSelect% 1
			CopyPlugin "100_merged\\JPBooks_Merged(V+S+M).esp" "JPBooks_Merged(V+S+M).esp"
			LoadEarly "JPBooks_Merged(V+S+M).esp"
			SetVar InstallFiles "JPBooks_Merged(V+S+M).esp%NewLine%"
		EndIf
		; + morrowindJPbooks_light
		If Equal %FlagMWJPBKSSelect% 2
			CopyPlugin "100_merged\\JPBooks_Merged(V+S+ML).esp" "JPBooks_Merged(V+S+ML).esp"
			LoadEarly "JPBooks_Merged(V+S+ML).esp"
			SetVar InstallFiles "JPBooks_Merged(V+S+ML).esp%NewLine%"
		EndIf
	EndIf

;Separated
Else
	; JPBooks
	If Equal %FlagJPBooks% 1
		CopyPlugin "010_JPBooks\\JPBooks_Vanilla.esp" "JPBooks_Vanilla.esp"
		LoadEarly "JPBooks_Vanilla.esp"
		SetVar InstallFiles "JPBooks_Vanilla.esp%NewLine%"
	EndIf
	If Equal %FlagJPBooks% 2
		CopyPlugin "010_JPBooks\\JPBooks_Vanilla+SI.esp" "JPBooks_Vanilla+SI.esp"
		LoadEarly "JPBooks_Vanilla+SI.esp"
		SetVar InstallFiles "JPBooks_Vanilla+SI.esp%NewLine%"
	EndIf

	; morrowindJPbooks
	If Equal %FlagMWJPBKS% 1
		If Equal %FlagMWJPBKSSelect% 1
			CopyPlugin "020_morrowindjpbooks\\morrowindJPbooks.esp" "morrowindJPbooks.esp"
			LoadEarly "morrowindJPbooks.esp"
			SetVar InstallFiles "%InstallFiles%morrowindJPbooks.esp%NewLine%"
		EndIf
		If Equal %FlagMWJPBKSSelect% 2
			CopyPlugin "020_morrowindjpbooks\\morrowindJPbooks_light.esp" "morrowindJPbooks_light.esp"
			LoadEarly "morrowindJPbooks_light.esp"
			SetVar InstallFiles "%InstallFiles%morrowindJPbooks_light.esp%NewLine%"
		EndIf
	EndIf

EndIf

;-------------------------------------------------------------------
; 結果表示
;-------------------------------------------------------------------
If DialogYesNo "以下のファイルがインストールされます。%NewLine%実行する場合はYes(はい)、キャンセルする場合はNo(いいえ)を選んで下さい%NewLine%%NewLine%%InstallFiles%", \
               "Install"
	; do nothing
Else
	Message "インストールがキャンセルされました" "Notice"
	FatalError
EndIf